Die Funktion WENN ermöglicht einen logischen Vergleich zwischen einem aktuellen Wert und einem erwarteten Wert. Dazu wird auf eine Bedingung geprüft und ein Ergebnis zurückgegeben, wenn die Bedingung WAHR oder FALSCH ist.
-
WENN(ein Wert wahr ist, tue dieses, andernfalls tue etwas anderes)
Was geschieht jedoch, wenn Sie mehrere Bedingungen prüfen müssen, die beispielsweise alle WAHR oder FALSCH ergeben müssen (UND), oder wenn nur eine Bedingung WAHR oder FALSCH ergeben muss (ODER) oder wenn Sie prüfen möchten, ob eine Bedingung Ihre Kriterien NICHT erfüllt? Alle drei Funktionen können zwar eigenständig verwendet werden, werden aber viel häufiger mit der Funktion WENN kombiniert.
Verwenden Sie die Funktion WENN mit UND, ODER und NICHT, um mehrfach zu prüfen, ob Bedingungen WAHR oder FALSCH sind.
Syntax
-
WENN(UND()) - WENN(UND(Wahrheitswert1; [Wahrheitswert2]; ...); Dann_Wert; [Sonst_Wert]))
-
WENN(ODER()) - WENN(ODER(Wahrheitswert1; [Wahrheitswert2]; ...); Dann_Wert; [Sonst_Wert]))
-
WENN(NICHT()) - WENN(NICHT(Wahrheitswert1); Dann_Wert; [Sonst_Wert]))
| Argumentname | Beschreibung | |
| Prüfung (erforderlich) | Die zu prüfende Bedingung. | |
| Dann_Wert (erforderlich) | Der Wert, der zurückgegeben werden soll, wenn das Ergebnis der Wahrheitsprüfung WAHR ist. | |
| Sonst_Wert (optional) | Der Wert, der zurückgegeben werden soll, wenn das Ergebnis der Wahrheitsprüfung FALSCH ist. | |
Im Folgenden eine Übersicht darüber, wie die Funktionen UND, ODER und NICHT im Einzelnen strukturiert werden. Wenn Sie sie jeweils mit einer WENN-Anweisung kombinieren, ergeben sich folgende Funktionen:
-
UND – =WENN(UND(etwas ist WAHR; etwas anderes ist WAHR); Dann_Wert; Sonst_Wert)
-
ODER – =WENN(ODER(etwas ist WAHR; etwas anderes ist WAHR); Dann_Wert; Sonst_Wert)
-
NICHT – =WENN(NICHT(etwas ist WAHR); Dann_Wert; Sonst_Wert)
Beispiele
Im Folgenden einige Beispiele für allgemeine geschachtelte Anweisungen in der Form WENN(UND()), WENN(ODER()) und WENN(NICHT()). Obwohl die Funktionen UND und ODER bis zu 255 einzelne Bedingungen unterstützen können, wird von der übermäßigen Verwendung abgeraten, da sich die Erstellung, Überprüfung und Verwaltung komplexer, geschachtelter Formeln als schwierig erweisen kann. Die Funktion NICHT akzeptiert nur eine Bedingung.
Nachfolgend sind die Formeln gemäß ihrer Logik aufgeschlüsselt:
| Formel | Beschreibung |
|---|---|
| =WENN(UND(A2>0;B2<100);WAHR; FALSCH) | WENN A2 (25) größer als 0 UND B2 (75) kleiner als 100 ist, WAHR zurückgeben, andernfalls FALSCH zurückgeben. In diesem Fall sind beide Bedingungen WAHR, sodass WAHR zurückgegeben wird. |
| =WENN(UND(A3="Red";B3="Green");WAHR;FALSCH) | WENN A3 ("Blue") = "Red" UND B3 ("Green") = "Green", WAHR zurückgeben, andernfalls FALSCH zurückgeben. In diesem Fall ist nur die erste Bedingung WAHR, sodass FALSCH zurückgegeben wird. |
| =WENN(ODER(A4>0;B4<50);WAHR; FALSCH) | WENN A4 (25) größer als 0 ODER B4 (75) kleiner als 50 ist, WAHR zurückgeben, andernfalls FALSCH zurückgeben. In diesem Fall ist nur die erste Bedingung WAHR. Da bei ODER aber nur ein Argument WAHR ergeben muss, gibt die Formel WAHR zurück. |
| =WENN(ODER(A5="Red";B5="Green");WAHR;FALSCH) | WENN A5 ("Blue") = "Red" ODER B5 ("Green") = "Green", WAHR zurückgeben, andernfalls FALSCH zurückgeben. In diesem Fall ist das zweite Argument WAHR, sodass die Formel WAHR zurückgibt. |
| =WENN(NICHT(A6>50);WAHR;FALSCH) | WENN A6 (25) NICHT größer als 50 ist, WAHR zurückgeben, andernfalls FALSCH zurückgeben. 25 ist in diesem Fall nicht größer als 50, sodass die Formel WAHR zurückgibt. |
| =WENN(NICHT(A7="Red");WAHR;FALSCH) | WENN A7 ("Blue") NICHT gleich "Red" ist, WAHR zurückgeben, andernfalls FALSCH zurückgeben. |
Beachten Sie, dass in allen Beispielen nach den jeweiligen Bedingungen eine schließende Klammer steht. Die übrigen WAHR/FALSCH-Argumente sind dann Teil der äußeren WENN-Anweisung. Sie können die WAHR-/FALSCH-Werte auch durch Text oder numerische Werte ersetzen und diese in den Beispielen zurückgeben lassen.
Im Folgenden einige Beispiele für die Verwendung von UND, ODER und NICHT zum Auswerten von Datumswerten.
Nachfolgend sind die Formeln gemäß ihrer Logik aufgeschlüsselt:
| Formel | Beschreibung |
|---|---|
| =WENN(A2>B2;WAHR;FALSCH) | WENN A2 größer als B2 ist, WAHR zurückgeben, andernfalls FALSCH zurückgeben. 12.03.14 ist größer als 01.01.14, sodass die Formel WAHR zurückgibt. |
| =WENN(UND(A3>B2;A3<C2);WAHR;FALSCH) | WENN A3 größer als B2 UND A3 kleiner als C2 ist, WAHR zurückgeben, andernfalls FALSCH zurückgeben. In diesem Fall sind beide Argumente WAHR, sodass die Formel WAHR zurückgibt. |
| =WENN(ODER(A4>B2;A4<B2+60);WAHR;FALSCH) | WENN A4 größer als B2 ODER A4 kleiner als B2 + 60 ist, WAHR zurückgeben, andernfalls FALSCH zurückgeben. In diesem Fall ist das erste Argument WAHR, das zweite aber FALSCH. Da bei ODER nur eines der Argumente WAHR sein muss, gibt die Formel WAHR zurück. Wenn Sie den Formelauswertungs-Assistenten auf der Registerkarte "Formel" verwenden, können Sie nachvollziehen, wie die Formel von Excel ausgewertet wird. |
| =WENN(NICHT(A5>B2);WAHR;FALSCH) | WENN A5 nicht größer als B2 ist, WAHR zurückgeben, andernfalls FALSCH zurückgeben. In diesem Fall ist A5 größer als B2, sodass die Formel FALSCH zurückgibt. |
Verwendung von UND, ODER und NICHT mit bedingter Formatierung
Sie können UND, ODER und NICHT auch verwenden, um Kriterien für die bedingte Formatierung mit der Formeloption festzulegen. In diesem Fall können Sie UND, ODER und NICHT eigenständig verwenden und auf die Funktion WENN verzichten.
Klicken Sie auf der Registerkarte Start auf Bedingte Formatierung > Neue Regel. Wählen Sie als Nächstes die Option Formel für die Ermittlung der zu formatierenden Zellen verwenden aus, geben Sie die Formel ein, und wenden Sie das gewünschte Format an.
Bei Verwendung unseres früheren Beispiels zu Datumsangaben würden die Formeln wie folgt aussehen.
| Formel | Beschreibung |
|---|---|
| =A2>B2 | Wenn A2 größer als B2 ist, Zelle formatieren, andernfalls nichts unternehmen. |
| =UND(A3>B2;A3<C2) | Wenn A3 größer als B2 UND A3 kleiner als C2 ist, Zelle formatieren, andernfalls nichts unternehmen. |
| =ODER(A4>B2;A4<B2+60) | Wenn A4 größer als B2 ODER A4 kleiner als B2 plus 60 (Tage) ist, Zelle formatieren, andernfalls nichts unternehmen. |
| =NICHT(A5>B2) | Wenn A5 NICHT größer als B2 ist, Zelle formatieren, andernfalls nichts unternehmen. In diesem Fall ist A5 größer als B2, sodass das zurückgegebene Ergebnis FALSCH lautet. Wenn Sie die Formel in =NICHT(B2>A5) ändern würden, würde sie WAHR zurückgeben und die Zelle formatiert werden. |
Hinweis:Ein häufiger Fehler bei der Eingabe einer Formel für bedingte Formatierung besteht darin, das Gleichheitszeichen (=) zu vergessen. In diesem Fall werden der Formel im Dialogfeld "Bedingte Formatierung" das Gleichheitszeichen und Anführungszeichen hinzugefügt (="ODER(A4>B2;A4<B2+60)"), und Sie müssen die Anführungszeichen entfernen, bevor die Formel ordnungsgemäße Ergebnisse liefert.
Benötigen Sie weitere Hilfe?
Siehe auch
Sie können jederzeit einen Experten in der Excel Tech Community fragen oder Unterstützung in den Communities erhalten.
Erfahren Sie, wie verschachtelte Funktionen in einer Formel verwendet werden
WENN (Funktion)
UND
ODER
NICHT
Übersicht über Formeln in Excel
Vermeiden defekter Formeln
Ermitteln von Fehlern in Formeln
Tastenkombinationen in Excel
Logische Funktionen (Referenz)
Excel-Funktionen (alphabetisch)
Excel-Funktionen (nach Kategorie)
